
 1000  *SAVE S.DISPLAY FILE
 1010  *--------------------------------
 1020  *      PATCH DOS TO CHANGE VERIFY
 1030  *      INTO DISPLAY
 1040  *--------------------------------
 1050  MON.PRNTAX .EQ $F941
 1060  MON.PRBL2  .EQ $F94A
 1070  MON.CROUT  .EQ $FD8E
 1080  MON.PRBYTE .EQ $FDDA
 1090  MON.COUT   .EQ $FDED
 1100  *--------------------------------
 1110         .OR $300
 1120  *--------------------------------
 1130  PATCH  LDA #DISPLAY      HOOK INTO VERIFY COMMAND
 1140         STA $AD1C
 1150         LDA /DISPLAY
 1160         STA $AD1D
 1170         RTS
 1180  *--------------------------------
 1190  UNPATCH
 1200         LDA #$B0B6        RESTORE NORMAL VERIFY
 1210         STA $AD1C
 1220         LDA /$B0B6
 1230         STA $AD1D
 1240         RTS
 1250  *--------------------------------
 1260  DISPLAY
 1270         JSR MON.CROUT     START SECTOR WITH <RET>
 1280         JSR $B0B6         READ NEXT SECTOR
 1290         BCS .1            END OF FILE
 1300         LDY #0            DISPLAY FIRST HALF SECTOR
 1310         JSR SHOW
 1320         JSR SHOW          DISPLAY SECOND HALF
 1330         CLC               SIGNAL NOT END OF FILE
 1340  .1     RTS
 1350  *--------------------------------
 1360  SHOW   LDA $B5E5    DISPLAY SECTOR POSITION
 1370         LDX $B5E4
 1380         JSR MON.PRNTAX
 1390         LDA #16      16 LINES PER BLOCK
 1400         STA LCNT
 1410         BNE .2       ...ALWAYS
 1420  .1     LDX #4       PRINT 4 BLANKS
 1430         JSR MON.PRBL2     SO COLUMNS LOOK NEATER
 1440  .2     LDA #8       8 BYTES PER LINE
 1450         STA BCNT
 1460         TYA          PRINT BYTE COUNT
 1470         JSR MON.PRBYTE
 1480         LDA #"-"     PRINT "-"
 1490         JSR MON.COUT
 1500  .3     LDA #" "     PRINT " "
 1510         JSR MON.COUT
 1520         LDA ($42),Y  NEXT BYTE FROM FILE
 1530         INY
 1540         JSR MON.PRBYTE
 1550         DEC BCNT
 1560         BNE .3       MORE TO THIS LINE
 1570         JSR MON.CROUT     NEXT LINE
 1580         DEC LCNT
 1590         BNE .1
 1600         RTS
 1610  *--------------------------------
 1620  BCNT   .BS 1
 1630  LCNT   .BS 1
 1640  *--------------------------------

